ZBasic Forum

Code: Select all

Option TargetDevice zx1280
Option ExtRamConfig On
Option RAMSize 65536 - Register.RamStart
Sum Main()
Debug.Print "RAMSize=";CStr(Register.RAMSize)
Debug.Print "ExtRAM = "; Cstr(Register.ExtRamConfig)
End Sub

Returns: 
ZBasic v2.6.3
RAM Size = 7552
ExtRAM = 128

Code: Select all

#if Option.ExtRamAble
Option ExtRamConfig Off
#endif

Private msg as StringVectorData({ " says...", "    Hello, world" })
Private device as String

Private Const cmdChar as Byte = &H04

#if Option.TargetCode = "Native"
    Private Const stackSize as Integer = 200
#else
    Private Const stackSize as Integer = 50
#endif

Private taskStack(1 to stackSize) as Byte

Sub Main()
    Dim j as Integer

#if Option.ExtRamAble
    Debug.Print "RAM Size is "; Register.RamSize; " bytes"
#endif

    ' launch the ATN detection task
    CallTask cmdTask, taskStack

    ' get the device identification string
    device = getDeviceID()

    ' loop forever displaying the hello world message
    j = 1
    Do
        Call Hello(j)
    Loop
End Sub

'
'' Hello
'
' This subroutine displays one of two strings depending on the
' passed index (of which only the least significant bit is used).
'
Private Sub Hello(ByRef idx as Integer)
    ' advance the string index and limit its value
    idx = (idx + 1) And 1

    ' display the indexed string, for string 0, add the device identifier prefix
    If (idx = 0) Then
        Debug.Print device;
    End if
    Debug.Print msg(idx + 1)

#if defined(Pin.RedLED) And defined(Pin.GreenLED)
    ' for devices with LEDs, flash the red and green LEDs for a half second each
    Call PutPin(Pin.RedLED, zxOutputLow)
    Call Delay(0.5)
    Call PutPin(Pin.RedLED, zxOutputHigh)
    Call PutPin(Pin.GreenLED, zxOutputLow)
    Call Delay(0.5)
    Call PutPin(Pin.GreenLED, zxOutputHigh)
#else
    ' for devices without LEDs, simply delay for a second
    Call Delay(1.0)
#endif
End Sub

'
'' getDeviceID
'
' Retrieve the device identifer and return it as a string.
'
Private Function getDeviceID() as String
    Dim idLen as Integer
    Dim i as Integer
    Dim id(1 to 10) as Byte

    ' note that the 'id' array will be null terminated
    Call System.DeviceID(id)

    ' determine the length of the identification string
    idLen = 0
    For i = 1 to UBound(id)
        If (id(i) = 0) Then
            Exit For
        End If
        idLen = idLen + 1
    Next i

    ' create a string containing the identification string
    getDeviceID = MakeString(id.DataAddress, idLen)
End Function

'
'' cmdTask
'
' The sole purpose of this task is to check the input queue for the ATN
' character and, when found, invoke the ZX command mode.
'
Sub cmdTask()
    Do
        If (StatusQueue(CByteArray(Register.RxQueue))) Then
            Dim c as Byte
            Call GetQueue(CByteArray(Register.RxQueue), c, 1)
            If (c = cmdChar) Then
                Call ZXCmdMode(False)
            End If
        End If
        Call Sleep(0)
    Loop
End Sub

Code: Select all

...
Verification complete.
ZBasic v2.6.3
RAM Size is 7552 bytes
ZX1280 says...
        Hello, world
...
...

Code: Select all

Option ExtRamConfig On

Code: Select all

ZX1280 v2.6.3 012e,5516
Downloading file "C:\zbasic\New Folder\zx1280test.zxb":
........................
Download complete.
Verifying download:
........................
Verification complete.
ZBasic v2.6.3
RAM Size is 64384 bytes
ZX1280 says...
    Hello, world