Hello_World puzzler

[GTBecker]

Here's something like the Hello_World that ZX devices run when new (plus Com9):

Code: Select all

'	option ConsoleSpeed 0
	option TargetDevice ZX24x
Private devId(1 to 10) as Byte
Private devName as String
Private Com1InQ(1 to 20) as Byte
Private Com1OutQ(1 to 20) as Byte
Private Com9InQ(1 to 20) as Byte
Private Com9OutQ(1 to 20) as Byte
Private Const crlf as string = chr(13) & chr(10)
Private	say(1) as string

Public Sub Main()
'	Call OpenQueue(Com1InQ, SizeOf(Com1InQ))
'	Call OpenQueue(Com1OutQ, SizeOf(Com1OutQ))
'	Call OpenCom(1, 19200, Com1InQ, Com1OutQ) 
	
	Call OpenQueue(Com9InQ, SizeOf(Com9InQ))
	Call OpenQueue(Com9OutQ, SizeOf(Com9OutQ))
	Call OpenCom(9, 9600, Com9InQ, Com9OutQ)
	
	' get device name
	System.DeviceID(devID)
	devName = MakeString(devId.DataAddress, SizeOf(devID))
	Dim i as byte
	i = StrFind(devName, Chr(0))
	If &#40;i <> 0&#41; Then
		devName = Left&#40;devName, i-1&#41;
	End If

	say&#40;0&#41; = devName & " says..."
	say&#40;1&#41; = "   Hello, world!"

	Do	' endless
		' alernate LEDs, say hello
		Call Hello&#40;0&#41;
		Call Hello&#40;1&#41;
	Loop
End Sub

Private sub Hello&#40;ByVal i as byte&#41;
	Debug.Print say&#40;i&#41;
'	Call PutQueueStr&#40;Com1OutQ, say&#40;i&#41; & crlf&#41;
	Call PutQueueStr&#40;Com9OutQ, say&#40;i&#41; & crlf&#41;
	Call PutPin&#40;Pin.RedLED, 0&#41;
	Call Delay&#40;0.5&#41;
	Call PutPin&#40;Pin.RedLED, 1&#41;
	Call PutPin&#40;Pin.GreenLED, 0&#41;
	Call Delay&#40;0.5&#41;
	Call PutPin&#40;Pin.GreenLED, 1&#41;	
End Sub

If Com1 uses Debug.Print it works but if Com1 opens queues and its port, and uses PutQueueStr, it fails. What am I missing?

[GTBecker]

In contrast to the -24x behavior, the code above works on a -24n (excepting Com9, of course) whether using Debug.Print or opened Com1 and PutQueueStr().

Later edit: the -24n worked apparently because Option SignOn Off had been expressed in earlier code and remains that way in persistent ram if not reexpressed.

[GTBecker]

This code appears to show that Option SignOn On causes native devices (at least the -24n and -24x) to crash if OpenCom1 is called before the signon string makes it out:

Code: Select all

   option TargetDevice ZX24x
   option SignOn On
Private Com1InQ(1 to 30) as Byte
Private Com1OutQ(1 to 30) as Byte

Public Sub Main()

   call delay(0.002)

   Call OpenQueue(Com1InQ, SizeOf(Com1InQ))
   Call OpenQueue(Com1OutQ, SizeOf(Com1OutQ))

   Call OpenCom(1, 19200, Com1InQ, Com1OutQ)

   Call PutQueueStr(Com1OutQ, "via PutQueue")
End Sub

Either increasing the delay period >=0.006S or commenting the OpenCom1 allows "ZBasic v4.1.3" (and the subsequent "via PutQueue") to appear - otherwise the machine crashes when Com1 tries to open.

[dkinzer]

If Com1 uses Debug.Print it works but if Com1 opens queues and its port, and uses PutQueueStr, it fails. What am I missing?

The problem here is that the serial channel is being re-configured in the middle of the outputting of the sign on message. You can add a loop just before opening Com1 to ensure that outputting of the sign on message has completed.

Code: Select all

Do While &#40;&#40;StatusCom&#40;1&#41; And &H04&#41; <> 0&#41;
Loop

An alternate strategy is to turn off the sign on message using Option SignOn Off.

[GTBecker]

Further, it appears that Option ConsoleSpeed 0 does not behave in native devices as documented:

"For native mode devices, the console speed can be set to zero thereby requesting that the console serial channel not be open initially. In this case, if you want to use the console serial channel you must specifically open it."

With Option ConsoleSpeed 0, on a -24x, opening Com1 to 19200 appears to work, but a subsequent PutQueueStr to Com1 resets the machine.

Code: Select all

    option ConsoleSpeed 0
   option TargetDevice ZX24x
   option SignOn Off
Private Com1OutQ(1 to 30) as Byte

Public Sub Main()
   Call OpenQueue(Com1OutQ, SizeOf(Com1OutQ))
   Call OpenCom(1, 19200, 0, Com1OutQ)
   Call PutPin(Pin.RedLED, 0)
   
   Call PutQueueStr(Com1OutQ, "via PutQueue")
   Call PutPin(Pin.RedLED, 1)
   Call PutPin(Pin.GreenLED, 0)
End Sub

If ConsoleSpeed is zero, the red LED flashes as the machine is repeatedly reset when PutQueueStr is called. If set to 19200, the code succeeds and the green LED is lit.

Do I misunderstand ConsoleSpeed 0?

[dkinzer]

With Option ConsoleSpeed 0, on a -24x, opening Com1 to 19200 appears to work, but a subsequent PutQueueStr to Com1 resets the machine.

In this specific case, the ZBasic compiler is not emitting the code necessary to include the ISRs for Com1. Consequently, when data is put in the queue and an interrupt is thus generated the device resets.

You can work around the issue by adding the code below to your Main() subroutine, before any code or data declarations.

Code: Select all

#c
   ZB_REQUEST_SYM(zb_com1_ISR);
#endc

I believe that we have located the source of the problem and identified a solution. We'll post an update to the compiler when testing has been completed.

[GTBecker]

Thanks, Don. Both remedies work.

[dkinzer]

We'll post an update to the compiler when testing has been completed.

Now available as v4.1.6 on the Downloads Page. The update is not yet in the installer so download the .zip file and extract the executable to the ZBasic installation directory, copying or renaming the existing ZBasic.exe first if a backup is desired.

[jay]

I've been having a somewhat similar problem, except, I'm running with the generic license on a AtMega328P and using just debug.print... it is a slightly modified version of Don's "Hello, world" example he posted to me 14 December 2008 in the zx-1281 topic.

While trying to understand my problem, I found that with "SignOn ON" and the CallTask cmdTask, taskStack commented out, getDeviceID() returns 0f0f0f0f. Running the Calltask, getDeviceID() returns 1e950f (correct device). When SignOn is OFF, getDeviceID() workes correctly with or without the Calltask. I also found at times, when SignOn had never been specified (on a new device), letting CallTask (ZXCmdMode) run, would not allow the program to start from power up. I had to download the application to restart. I tried with v4.1.7 compiler, Signon displays ZBasic v4.1.3 ..

Also, verified the ZB_REQUEST_SYM and StatusCom(!) do loop mentioned previously had no effect.

It appears SignOn Off solves all the issues.

Regards,

..jay

Modified code...

Code: Select all

Option TargetDevice ATMega328P
Option DeviceParameter package "PDIP-28"
Option DeviceParameter clockFrequency 14745600
Option ConsoleSpeed 57600
Option DeviceParameter rtcFrequency 512
Option DeviceParameter rtcScale 2
Option DeviceParameter swUartDivisor 64
Option DeviceParameter swUartMinSpeed 300
Option DeviceParameter swUartMaxSpeed 19200
Option DeviceParameter swUartBaseSpeed 0
Option DeviceParameter timerSpeed1Divisor 1
Option DeviceParameter timerSpeed2Divisor 8
Option DeviceParameter ZBasicBootloader true
Option SignOn Off

#define RedLed = D.2
#define GreenLed = D.3

Private msg as StringVectorData({ " says...", "    Hello, world" })
Private device as String

Private Const cmdChar as Byte = &H04

Private Const stackSize as Integer = 200

Private taskStack(1 to stackSize) as Byte

Sub Main()
    Dim j as Integer

    ' launch the ATN detection task
    CallTask cmdTask, taskStack

    ' get the device identification string
    device = getDeviceID()

    ' loop forever displaying the hello world message
    j = 1
    Do
        Call Hello(j)
    Loop

End Sub

'
'' Hello
'
' This subroutine displays one of two strings depending on the
' passed index (of which only the least significant bit is used).
'
Private Sub Hello(ByRef idx as Integer)
    ' advance the string index and limit its value
    idx = (idx + 1) And 1

    ' display the indexed string, for string 0, add the device identifier prefix
    If (idx = 0) Then
        Debug.Print device;
    End if
    Debug.Print msg(idx + 1)

#if defined(RedLED) And defined(GreenLED)
    ' for devices with LEDs, flash the red and green LEDs for a half second each
    Call PutPin(RedLED, zxOutputLow)
    Call Delay(0.25)
    Call PutPin(RedLED, zxOutputHigh)
    Call PutPin(GreenLED, zxOutputLow)
    Call Delay(0.25)
    Call PutPin(GreenLED, zxOutputHigh)
#else
    ' for devices without LEDs, simply delay for a second
    Call Delay(1.0)
#endif
End Sub

'
'' getDeviceID
'
' Retrieve the device identifer and return it as a string.
'
Private Function getDeviceID() as String
    Dim idLen as Integer
    Dim i as Integer
    Dim id(1 to 10) as Byte

    ' note that the 'id' array will be null terminated
    Call System.DeviceID(id)

    ' determine the length of the identification string
    idLen = 0
    For i = 1 to UBound(id)
        If (id(i) = 0) Then
            Exit For
        End If
        idLen = idLen + 1
    Next i

    ' create a string containing the identification string
    getDeviceID = MakeString(id.DataAddress, idLen)
End Function

'
'' cmdTask
'
' The sole purpose of this task is to check the input queue for the ATN
' character and, when found, invoke the ZX command mode.
'
Sub cmdTask()
    Do
        If (StatusQueue(CByteArray(Register.RxQueue))) Then
            Dim c as Byte
            Call GetQueue(CByteArray(Register.RxQueue), c, 1)
            If (c = cmdChar) Then
                Call ZXCmdMode()  ' 
            End If
        End If
        Call Sleep(0)
    Loop
End Sub